#Fröccs feladat:
#				BOR			SZÓDA			ÁR
#Kisfröccs		1			1				200
#Nagyfröccs		2			1				330
#Hosszú lépés		1			2				210
#Házmester		3			2				470
#Viceházmester	2			3				400
#Krúdy fröccs		9			1				1500
#Sóher fröccs		1			9				300
#Puskás fröccs	6			3				900
#Házi úr			4			1				600
#Lakófröccs		1			4				250

#Van 100 l borom, és 150 l szódám. 
#Feladat a bevételem maximalizálása.

#Megoldás:
 
 #Sets and parameters
 set Froccs;
 set Ingridients;
 param HowMany {Froccs, Ingridients};
 param Price {Froccs};
 param Use {Ingridients};
 #variables
var Sale {Froccs} >=0, integer;

#Constraints - Korlátozások
s.t. UseIngridients{i in Ingridients} : sum{f in Froccs} HowMany[f,i] *Sale[f] <= Use[i];

#Objectives -célfüggvény
maximize TotalIncome: sum {f in Froccs} Sale[f] * Price[f];

# DATA kulcsszó
data;
#értékek és paraméterek
set Froccs: KF NF HL HM VHM KRF SF PF HU LF;
set Ingridients: Wine Soda;

param HowMany:
		Wine		Soda:=
KF		1			1
NF		2			1
HL		1			2
HM		3			2
VHM		2			3
KRF		9			1
SF		1			9
PF		6			3
HU		4			1
LF		1			4
;
param Price:=
KF		200
NF		330
HL		210
HM		470
VHM		400
KRF		1500
SF		300
PF		900
HU		600
LF		250
;
param Use:=
Wine 1000
Soda 1500
;
